@echo off

rem ========== エディタ ==============
PATH %windir%\system32
set EDITOR=notepad.exe

rem ↓他のエディタを使う場合（例：秀丸：remは外すこと）
rem PATH=C:\Program Files\Hidemaru
rem set EDITOR=Hidemaru.exe


set SFILE=c:\sdirtmp.wk.txt
set DFILE=c:\ddirtmp.wk.txt
set RFILE=c:\rdirtmp.wk.txt

set EXT=*.*

set SFN=
set DFN=
set BFN=

call :CHEKTMPFILES

rem 以下の二行のremを外すとワイルドカードを使った指定ができる(*.avi等）
rem echo 対象ファイルを入力してください【 %EXT% 】
rem set /p FILEPAT=" >"


dir /B /on "%FILEPAT%" > %SFILE%
dir /B /on "%FILEPAT%" > %DFILE%


%EDITOR% %DFILE%


set COUNT=0
for /F %%i in (%SFILE%) do call :BINDLINES

type %RFILE%

:CHKPRM
set OK= 
set /p OK="以上のようにリネームしてよろしいですか？(y=リネーム実行 n=終了)"
if "%OK%"=="y" goto DORENAME
if "%OK%"=="n" goto FINISH
goto CHKPRM

:DORENAME

set COUNT=0
for /F "delims=` eol=`" %%i in (%RFILE%) do call :RNM %%i

:FINISH
call :DELTMPFILES
goto :EOF

rem ------------------------------

:RNM
set /a COUNT=%COUNT%+1
if %COUNT%==1 exit /b
set DATA=%1
set DATA=%DATA:―→= %


rename %DATA%
exit /b

:BINDLINES

set /a COUNT=%COUNT%+1

call :READLINE %SFILE%
set SFN=%DATA%
call :READLINE %DFILE%
set DFN=%DATA%

rem set DFN=%DFN:^%=％%
rem set DFN=%DFN:^"=”%
rem set DFN=%DFN:^*=＊%

set DFN=%DFN:\=￥%
set DFN=%DFN:/=／%
set DFN=%DFN::=：%
set DFN=%DFN:<=＜%
set DFN=%DFN:>=＞%
set DFN=%DFN:|=｜%
set DFN=%DFN:?=？%
set DFN=%DFN:	=_%
set DFN=%DFN:!=！%

echo %SFN%―→%DFN% >> %RFILE% 
exit /b

:READLINE
set LCOUNT=0
set DATA=
for /F "delims=` eol=`" %%i in (%1) do call :READSUB "%%i"
exit /b

:READSUB
set /a LCOUNT=%LCOUNT%+1
if %LCOUNT%==%COUNT% set DATA=%1

exit /b

rem -----------------------------
:CHEKTMPFILES
echo dirlist > %SFILE%
echo dirlist > %DFILE%
echo dirlist > %RFILE%
exit /b


:DELTMPFILES
del %SFILE%
del %DFILE%
del %RFILE%
exit /b